Fanuc机器人回原位程序在自动化装配生产线上的应用

李世杰

Fanuc机器人回原位程序在自动化装配生产线上的应用

李世杰

（大连豪森瑞德设备制造有限公司，辽宁 大连 116036）

随着汽车工业的迅猛发展，机器人在先进汽车制造中的重要性也越来越凸显。Fanuc机器人作为机器人领域的巨头，为全球自动化生产作出了巨大的贡献。文章主要讲述在生产中，Fanuc搬运类机器人发生异常情况停止后安全自动回原位的方法。搬运机器人首先判断当前点在哪两个轨迹点之间，根据所处轨迹点位置，自行判断是松开夹具反向返回原位或者继续执行子工作路径至终点后。通过对应该终点的工位，调用对应该工位的返回路径程序控制机器人返回原位。通过编写程序使机器人快速返回原位，通过减少故障的处理时间来间接提高生产效率，增加企业利润，在生产中具有重要意义。

Fanuc机器人；应用；程序编写

前言

在汽车自动装配线设备的控制系统中，机器人技术的应用也越来越广泛，而它的出现是为了适应制造业规模化生产，解决单调、重复的体力劳动和提高生产质量而代替人工作业。

1 搬运机器人回原位说明

1.1 搬运机器人

搬运机器人一般指机器人上带夹具的机器人，机器人动作的时候需要夹爪松开和夹紧，工作顺序一般分为下面三个步骤：

（1）机器人在原位或者某一位置去抓件位置抓件。这段机器人程序夹爪为松开状态，程序中断可以执行回原位，同时也可以执行断点继续功能。回原位步骤为机器人逆向走位置。

（2）机器人到抓件位置夹爪夹紧后抓着工件去放件位置。这段机器人程序夹爪为夹紧状态，程序中断不可以执行回原位，只能执行断点继续功能。

（3）机器人到放件位置夹爪松开后返回原位，整个程序执行完毕。这段机器人程序夹爪为松开状态，程序中断可以执行断点继续功能，同时也可以执行回原位。回原位步骤为机器人正向走位置。

1.2 搬运机器人回原位程序说明

打开机器人程序 PNS0001 里调用P01_45T3_LOAD_ TO_PRESS 程序：

/PROG P01_45T3_LOAD_TO_PRESS

1: GO[1:ACKPRGNO]=1;

2: IF GO[1:ACKPRGNO]<>R[1],JMP LBL[1];

3: DO[21:PRG_RUN]=ON;

4: DO[158:LOAD_NOT_WORK]=ON;

5: DO[159:45T3_PRESS_NOT_WORK]=ON;

6: J PR[1:HOME] 100% FINE;

7: SKIP CONDITION DI[200:Homing Request]=ON;

//定义skip条件为 DI[200:HomingRequest]为 ON，意思为在以下带有skip的程序段中，一旦 DI[200:Homing Request]为 ON，则立即跳出该程序段，否则正常执行程序段，并跳转至对应 LBL

8:J PR[5:45T3_LOAD_PROCES] 100% CNT 100 Skip, LBL[5];

//DI[200:HomingRequest]一直为OFF，则机器人运动至PR[5:45T3_LOAD_PROCES]，之后跳转到LBL[5]；若执行中 DI[200:Homing Request]置ON，则跳出该段，并执行第下一行程序，跳转到 LBL[52]---即第一段回零程序

9:JMP LBL[52];

10: LBL[5];

11: L PR[9:45T3_LOAD_UP] 1000mm/sec FINE Skip, LBL[9];

12: JMP LBL[51];

13: LBL[9];

14: WAIT DI[158:LOAD_SAFE]=ON;

15: L PR[10:45T3_LOAD_POS] 100mm/sec FINE Skip, LBL[10];

16: JMP LBL[50];

17: LBL[10];

18: CALL GRASP_GRASP;

19: L PR[11:45T3_LOAD_UP] 1000mm/sec FINE;

20: DO[185:LOAD_TAKE_CHECK]=ON;

21: WAIT DI[185:LOAD_TAKE_OK]=ON;

22: DO[185:LOAD_TAKE_CHECK]=OFF;

23: DO[158:LOAD_NOT_WORK]=OFF;

24: J PR[15:45T3_PRESS_PROCS]100%CNT100;

25: L PR[19:45T3_PRESS_UP] 1000mm/sec FINE;

26: WAIT DI[159:45T3_PRESS_SAFE]=ON AND DI[164: 45T3_PRESS_NO_PART]=ON;

27: L PR[20:45T3_PRESS_POS] 150mm/sec FINE;

28: CALL GRASP_LOOSEN;

29: L PR[21:45T3_PRESS_UP] 500mm/sec FINE Skip, LBL[20];

30: JMP LBL[60];

31: LBL[20];

32: DO[187:45T3_PUT_CHECK]=ON;

33: WAIT DI[187:45T3_PUT_OK]=ON;

34: DO[187:45T3_PUT_CHECK]=OFF;

35: DO[159:45T3_PRESS_NOT_WORK]=OFF;

36: J PR[25:45T3_PRESS_PROCS] 100% CNT100 Skip, LBL[21];

37: JMP LBL[61];

38: LBL[21];

39: J PR[1:HOME] 100% FINE;

40: DO[23:PRG_CMP]=ON;

41: WAIT .50(sec);

42: END;

43: LBL[50];

44: L PR[9:45T3_LOAD_UP] 100mm/sec FINE;

45: LBL[51];

46: L PR[5:45T3_LOAD_PROCES] 100mm/sec FINE;

47: LBL[52];

48: CALL AUTO_ROBOT_TO_HOME;

49: LBL[60];

50: L PR[21:45T3_PRESS_UP] 100mm/sec FINE;

51: LBL[61];

52: L PR[25:45T3_PRESS_PROCS] 100mm/sec FINE;

53: CALL AUTO_ROBOT_TO_HOME;

54: LBL[1];

55: GO[2:FAULT_NO]=2;

56: MESSAGE[!Sub Programme Mismatch];

57: JMP LBL[1];

/POS

1.3 回原位程序段解析

（1）P01_45T3_LOAD_TO_PRESS程序的去抓件动作顺序为以下：

PR[1:HOME]→PR[5:45T3_LOAD_PROCES]→PR[9:45T3_ LOAD_UP] → PR[10:45T3_LOAD_POS]。

加入了第7行跳过指令的条件之后，一旦机器人停止，HMI回原位请求发出，机器人首先判断当前点在哪两个轨迹点之间，然后逆着正常轨迹点的顺序回到原位PR[1:HOME]，比如程序执行到第11行时，跳过指令的条件DI[200:Homing Request]满足，这时机器人TCP正处于PR[5:45T3_LOAD_ PROCES]与LPR[9:45T3_LOAD_UP]之间，跳过11行，立即执行第12行，跳转到标签LBL[51]，机器人会从当前位置按照PR[5:45T3_LOAD_PROCES]，PR[1:HOME]的顺序回退到原位。

（2）P01_45T3_LOAD_TO_PRESS程序的放件之后回原位的动作顺序为以下：

L PR[21:45T3_PRESS_UP]→PR[25:45T3_PRESS_ PRO- CS]→ PR[1:HOME]。

如果机器人程序执行到此刻外部触发急停之后，操作人员此时可以有两种选择，1是断点继续运行，2是HMI点击回原位请求，这两种选择在当前程序段中机器人行走轨迹是一样的，都是正向走位置。

如果选择第二种，加入了第32行跳过指令的条件之后，一旦机器人停止，HMI回原位请求发出，机器人首先判断当前点在哪两个轨迹点之间，之后回撤到上一个轨迹点或者执行到下一个轨迹点，再顺着正常轨迹点的顺序回到原位PR [1:HOME]，比如程序执行到第39行时，跳过指令的条件DI[200:Homing Request]满足，这时机器人TCP正处PR[21: 45T3_PRESS_UP]与PR[25:45T3_PRESS_PROCS]之间，跳39行，立即执行第40行，跳转到标签LBL[61]，机器人会从当前位置按照PR[25:45T3_PRESS_PROCS]，PR[1:HOME]的顺序回退到原位。

1.4 关于SKIP指令的具体说明

图1 跳过指令

例：

1：SKIP CONDITION DI[1]=ON[2]

2: JP [1] 100% FINE

3: LP [2] 1000mm/sec FINE skip,LBL[1]

4: JP [3] 50% FINE

5: LBL[1]

6. JP [4] 50% FINE

跳过指令在跳过条件尚未满足的情况下，跳到转移目的地标签。

机器人向目标位置移动的过程中，跳过条件满足时，机器人在中途取消动作，程序执行下一行的程序语句。跳过条件尚未满足的情况下，在结束机器人的动作后，跳到目的地标签行。

跳过条件指令，预先指定在跳过指令中使用的跳过条件（执行跳过指令的条件）。在执行跳过指令前，务须执行跳过条件指令。曾被指定的跳过条件，在程序执行结束，或者执行下一个跳过条件指令之前有效[1]。

2 结语

在汽车自动装配线上，部分工位的夹具较复杂，部分工位在机器人运行轨迹上存在障碍物等。如果操作人员人为将机器人回原位，效率较低且有碰撞风险。调用程序回原位对操作人员要求低，安全，可靠，快速，不会发生意外的碰撞，兼容性强，更为柔性。

[1] 王民.FANUC机器人常见故障及处理措施探讨[J].南方农机,2020, 51(12):37.

[2] 李亚巍,杨雷,段毅,等.基于Siemens PLC程序的FANUC机器人IO控制与调用[J].中国设备工程,2020(19):28-30.

Application of Fanuc Robot Homing Program in Automated Assembly Line

LI Shijie

( Dalian Haosen Equipment Manufacturing Co., Ltd., Liaoning Dalian 116036 )

With the rapid development of the automobile industry, the importance of robots in advanced automobile manufacturing has become more and more prominent. As a giant in the field of robotics, Fanuc robots have made great contributions to global automated production. The article mainly describes the method for Fanuc handling robot to return to the original position safely after an abnormal situation occurs in production. The handling robot first judges which two track points the current point is between, and judges whether it is loose according to the position of the track point. After opening the fixture and returning to the original position in the reverse direction or continuing to execute the sub-work path to the end point, call the return path program corresponding to the end point to control the robot to return to the original position through the station corresponding to the end point. By writing a program to make the robot return to its original position quickly, and indirectly improve the production efficiency by reducing the processing time of the fault, and increase the profit of the enterprise, it is of great significance in the production.

Fanuc robit; Application; Programming

U466

B

1671-7988(2021)23-136-03

U466

B

1671-7988(2021)23-136-03

10.16638/j.cnki.1671-7988.2021.023.038

李世杰，就职于大连豪森瑞德设备制造有限公司。